# Maintainer: Maksim Bondarenkov <maksapple2306@gmail.com>

_realname=edit
pkgbase=mingw-w64-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=2.0.0
pkgrel=1
pkgdesc="Terminal text editor from Microsoft (mingw-w64)"
arch=('any')
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
url='https://github.com/microsoft/edit'
msys2_repository_url='https://github.com/microsoft/edit'
license=('spdx:MIT')
makedepends=("${MINGW_PACKAGE_PREFIX}-rust")
optdepends=("${MINGW_PACKAGE_PREFIX}-icu: for Search and Replace functionality")
source=("${url}/archive/v${pkgver}/${_realname}-${pkgver}.tar.gz")
sha256sums=('f35da309c5f3d92b10e5c4b2267e4d5e29d809b2aa460e80326b11f7feba72a5')

prepare() {
  cd "${_realname}-${pkgver}"

  cargo fetch --locked --target "${RUST_CHOST}"
}

build() {
  cd "${_realname}-${pkgver}"

  # configure icu libraries and symbol naming
  export EDIT_CFG_ICUUC_SONAME="libicuuc78.dll"
  export EDIT_CFG_ICUI18N_SONAME="libicuin78.dll"
  export EDIT_CFG_ICU_EXPORT_SUFFIX="_78"
  # FIXME: split debuginfo is not supported for mingw host anyway
  # https://github.com/rust-lang/rust/blob/60dabef95a3de3ec974dcb50926e4bfe743f078f/compiler/rustc_target/src/spec/base/windows_gnu.rs#L111
  export CARGO_PROFILE_RELEASE_DEBUG=0
  cargo build --release --locked -p edit
}

package() {
  cd "${_realname}-${pkgver}"

  cargo install \
    --offline \
    --no-track \
    --frozen \
    --path crates/edit \
    --root "${pkgdir}${MINGW_PREFIX}"

  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
}
