# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>

_realname=dav2d
pkgbase=mingw-w64-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=0.0.1
pkgrel=1
pkgdesc='AV2 decoder from VideoLAN (mingw-w64)'
arch=('any')
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
url='https://code.videolan.org/videolan/dav2d'
msys2_repository_url='https://code.videolan.org/videolan/dav2d'
license=('spdx:BSD-2-Clause')
depends=(
)
makedepends=(
  "${MINGW_PACKAGE_PREFIX}-cc"
  "${MINGW_PACKAGE_PREFIX}-meson"
  "${MINGW_PACKAGE_PREFIX}-ninja"
  "${MINGW_PACKAGE_PREFIX}-nasm"
  git
)
source=("${_realname}::git+${url}.git#tag=${pkgver}")
sha256sums=('1b85312784eb5fbefba15a0b35f38a332f2b283f1ced2093fae066bc515e3e6d')

build() {
  MSYS2_ARG_CONV_EXCL="--prefix=" \
  meson setup \
    --prefix="${MINGW_PREFIX}" \
    --buildtype=plain \
    -Denable_docs=false \
    -Denable_examples=false \
    -Denable_tests=false \
    "${_realname}" "build-${MSYSTEM}"

  meson compile -C "build-${MSYSTEM}"
}

package() {
  meson install -C "build-${MSYSTEM}" --destdir "${pkgdir}"
  install -Dm644 "${_realname}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
}
