# Copyright (c) 2016-2024 Taylor Richberger <taylor@axfive.net> and Pavel
# Belikov
#
# Permission is hereby granted, free of charge, to any person obtaining a copy
# of this software and associated documentation files (the "Software"), to
# deal in the Software without restriction, including without limitation the
# rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
# sell copies of the Software, and to permit persons to whom the Software is
# furnished to do so, subject to the following conditions:
#
# The above copyright notice and this permission notice shall be included in
# all copies or substantial portions of the Software.
#
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
# FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
# IN THE SOFTWARE.

cmake_minimum_required(VERSION 3.10)

project(args LANGUAGES CXX VERSION 6.4.15 DESCRIPTION "A flexible single-header C++11 argument parsing library that is designed to appear somewhat similar to Python's argparse" HOMEPAGE_URL "https://github.com/Taywee/args")

include(GNUInstallDirs)

string(REPLACE "/${CMAKE_LIBRARY_ARCHITECTURE}" "" CMAKE_INSTALL_LIBDIR_ARCHIND "${CMAKE_INSTALL_LIBDIR}")

set(ARGS_MAIN_PROJECT OFF)
if (CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)
    set(ARGS_MAIN_PROJECT ON)
endif()

option(ARGS_BUILD_EXAMPLE "Build example" ON)
option(ARGS_BUILD_UNITTESTS "Build unittests" ON)

set(CMAKE_CONFIG_DEST "${CMAKE_INSTALL_LIBDIR_ARCHIND}/cmake/${PROJECT_NAME}")
set(PackagingTemplatesDir "${CMAKE_CURRENT_SOURCE_DIR}/packaging")

add_library(args INTERFACE)
target_include_directories(args INTERFACE
	$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}>
	$<INSTALL_INTERFACE:include>)

if(ARGS_MAIN_PROJECT)
    include(CMakePackageConfigHelpers)
    install(FILES args.hxx DESTINATION include)
    install(TARGETS args EXPORT args-targets)
    install(EXPORT args-targets
        FILE args-config.cmake
        NAMESPACE taywee::
        DESTINATION ${CMAKE_INSTALL_DATADIR}/cmake/args)

    write_basic_package_version_file("${CMAKE_CURRENT_BINARY_DIR}/args-config-version.cmake" COMPATIBILITY SameMajorVersion ARCH_INDEPENDENT)
    install(FILES "${CMAKE_CURRENT_BINARY_DIR}/args-config-version.cmake" DESTINATION lib/cmake/args)

    set(PKG_CONFIG_FILE_NAME "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.pc")
    configure_file("${PackagingTemplatesDir}/pkgconfig.pc.in" "${PKG_CONFIG_FILE_NAME}" @ONLY)
    install(FILES "${PKG_CONFIG_FILE_NAME}"
        DESTINATION "${CMAKE_INSTALL_DATADIR}/pkgconfig"
    )
endif()

if (ARGS_BUILD_EXAMPLE)
    add_executable(gitlike examples/gitlike.cxx)
    target_link_libraries(gitlike args)
    set_property(TARGET gitlike PROPERTY CXX_STANDARD 11)

    add_executable(completion examples/completion.cxx)
    target_link_libraries(completion args)
    set_property(TARGET completion PROPERTY CXX_STANDARD 11)
endif()

if (ARGS_BUILD_UNITTESTS)
    enable_testing()

    function(args_configure_test target)
        target_link_libraries(${target} args)
        target_include_directories(${target} PRIVATE
            ${CMAKE_CURRENT_SOURCE_DIR}/test)
        set_property(TARGET ${target} PROPERTY CXX_STANDARD 11)
        if (MSVC)
            target_compile_options(${target} PRIVATE /W4 /WX /bigobj)
        else ()
            target_compile_options(${target} PRIVATE
                -Wall -Wextra -Werror -pedantic -Wshadow -Wunused-parameter)
        endif ()
        if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL 22)
            target_compile_options(${target} PRIVATE -Wno-c2y-extensions)
        endif ()
    endfunction()

    # One test per primary .cxx in test/. A test may have additional
    # translation units named <basename>.aux*.cxx that get linked into
    # the same executable (used by the multi-TU inclusion test).
    file(GLOB ARGS_TEST_SOURCES CONFIGURE_DEPENDS
        "${CMAKE_CURRENT_SOURCE_DIR}/test/*.cxx")
    list(FILTER ARGS_TEST_SOURCES EXCLUDE REGEX "\\.aux[^/]*\\.cxx$")

    foreach (test_src ${ARGS_TEST_SOURCES})
        get_filename_component(test_name ${test_src} NAME_WE)
        set(target_name "argstest-${test_name}")
        file(GLOB aux_srcs CONFIGURE_DEPENDS
            "${CMAKE_CURRENT_SOURCE_DIR}/test/${test_name}.aux*.cxx")
        add_executable(${target_name} ${test_src} ${aux_srcs})
        args_configure_test(${target_name})
        add_test(NAME ${test_name} COMMAND ${target_name})
    endforeach ()
endif()

add_library(taywee::args ALIAS args)
export(
    TARGETS args
    NAMESPACE taywee::
    FILE "${CMAKE_CURRENT_BINARY_DIR}/args-targets.cmake")

set(CPACK_PACKAGE_NAME "${PROJECT_NAME}")
set(CPACK_PACKAGE_VERSION "${PROJECT_VERSION}")
set(CPACK_PACKAGE_VENDOR "${PROJECT_NAME} developers")
set(CPACK_PACKAGE_DESCRIPTION "${PROJECT_DESCRIPTION}")
set(CPACK_DEBIAN_PACKAGE_NAME "${CPACK_PACKAGE_NAME}")
set(CPACK_RPM_PACKAGE_NAME "${CPACK_PACKAGE_NAME}")
set(CPACK_PACKAGE_HOMEPAGE_URL "${PROJECT_HOMEPAGE_URL}")
set(CPACK_PACKAGE_MAINTAINER "${CPACK_PACKAGE_VENDOR}")
set(CPACK_DEBIAN_PACKAGE_MAINTAINER "${CPACK_PACKAGE_MAINTAINER}")
set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE")
set(CPACK_RESOURCE_FILE_README "${CMAKE_CURRENT_SOURCE_DIR}/README.md")

set(CPACK_DEBIAN_PACKAGE_NAME "lib${PROJECT_NAME}-dev")
set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6-dev")
set(CPACK_DEBIAN_PACKAGE_SUGGESTS "cmake, pkg-config, pkg-conf")

set(CPACK_RPM_PACKAGE_NAME "lib${PROJECT_NAME}-devel")
set(CPACK_RPM_PACKAGE_SUGGESTS "${CPACK_DEBIAN_PACKAGE_SUGGESTS}")

set(CPACK_DEB_COMPONENT_INSTALL ON)
set(CPACK_RPM_COMPONENT_INSTALL ON)
set(CPACK_NSIS_COMPONENT_INSTALL ON)
set(CPACK_DEBIAN_COMPRESSION_TYPE "xz")

include(CPack)
