# Maintainer: Dirk Stolle

_realname=4ti2
pkgbase=mingw-w64-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=1.6.15
pkgrel=1
pkgdesc="Software package for algebraic, geometric and combinatorial problems on linear spaces (mingw-w64)"
arch=('any')
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
url='https://4ti2.github.io/'
msys2_repository_url='https://github.com/4ti2/4ti2'
msys2_references=(
  'archlinux: 4ti2'
  'cygwin: lib4ti2'
  'gentoo: sci-mathematics/4ti2'
)
license=('spdx:GPL-2.0-or-later')
depends=("${MINGW_PACKAGE_PREFIX}-cc-libs"
         "${MINGW_PACKAGE_PREFIX}-glpk"
         "${MINGW_PACKAGE_PREFIX}-gmp"
         'bash')
makedepends=("${MINGW_PACKAGE_PREFIX}-autotools"
             "${MINGW_PACKAGE_PREFIX}-cc"
             'git')
source=("https://github.com/4ti2/4ti2/releases/download/Release_${pkgver//./_}/4ti2-${pkgver}.tar.gz")
sha256sums=('070e639398fda1a4665b3291e5ea80f2ba280d9bffd50656ad8482d471b96965')

prepare() {
  cd "${_realname}-${pkgver}"

  autoreconf -fiv
}

build() {
  mkdir -p "build-${MSYSTEM}" && cd "build-${MSYSTEM}"

  ../"${_realname}-${pkgver}"/configure \
    --prefix="${MINGW_PREFIX}" \
    --build="${MINGW_CHOST}" \
    --host="${MINGW_CHOST}" \
    --target="${MINGW_CHOST}" \
    --disable-static \
    --enable-shared

  # Fix overlinking (copied from Arch's PKGBUILD)
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

check() {
  cd "build-${MSYSTEM}"

  make check
}

package() {
  cd "build-${MSYSTEM}"

  make install DESTDIR="${pkgdir}"

  install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
}
