Retour à la page personnelle de Bernard Parisse.

# Chapitre 5 Matrices en terminale scientifique

## 5.1 Les matrices de rotation

Étant donné t∈ ℝ on considère :
A(t)=(

cos(t) | −sin(t)
sin(t) | cos(t)

)
Calculer A(t)n pour n∈ ℕ.
Calculer A(t)2−2cos(t)A(t)+I où I est la matrice identité d’odre 2.
En déduire que A(t) est inversible et que A(t)−1=A(−t).
Calculer A(t)n pour n∈ ℤ.
Montrer que dans un repère orthonormé (O;i,j), la matrice A(t) est la matrice de la rotation de centre O et d’angle t.
On tape :
A(t):=[[cos(t),-sin(t)],[sin(t),cos(t)]]
tlin(A(t)*A(t))
On obtient :
[[cos(2*t),-sin(2*t)],[sin(2*t),cos(2*t)]]
On tape :
assume(n,integer)
An(t):=[[cos(n*t),-sin(n*t)],[sin(n*t),cos(n*t)]]
tlin(An(t)*A(t))
On obtient :
[[cos(n*t+t),-sin(n*t+t)],[sin(n*t+t),cos(n*t+t)]]
Donc on a montré par récurrence que :
A(t)n=A(nt).
On tape :
tlin(A(t)`^`2-2*cos(t)*A(t)+idn(2))
On obtient :
[[0,0],[0,0]]
On en déduit que :
A(2cos(t)*I−A)=I On tape :
B(t):=normal(2*cos(t)*idn(2)-A(t))
B(t)
On obtient :
[[cos(t),sin(t)],[-sin(t),cos(t)]]
On tape :
B(t)-A(-t)
On obtient :
[[0,0],[0,0]]
Donc pour tout n∈ ℕ, on a A(t)−1=A(−t) et A(t)−n=A(−t)n=A(−nt).
Donc pour tout n∈ ℤ, on a A(t)n=A(nt).
Dans la rotation r de centre O et d’angle t :
le vecteur i se transforme en le vecteur : r(i)=cos(t)i+sin(t)j
le vecteur j se transforme en le vecteur : r(j)=−sin(t)i+cos(t)j
Donc :
r(x i+y j)=xr(i)+yr(j)=(xcos(t)−ysin(t))i+(xsin(t)+ycos(t))j
c’est à dire :
r(

x
y

)=(

cos(t) | −sin(t)
sin(t) | cos(t)

)(

x
y

)= A(t)(

x
y

)
On tape :
coordonnees(rotation(0,t,x+i*y))
On obtient :
[cos(t)*x-sin(t)*y,cos(t)*y+x*sin(t)]

## 5.2 Les matrices magiques d’odre 3

### 5.2.1 Résultat préliminaire

Soit A la matrice :
A=[[a00,a01,a02],[a10,a11,a12],[a20,a21,a22]] Montrer que :
B=1/2*(A+tran(A)) est une matrice symértrique et
C=1/2*(A−tran(A)) est une matrice antisymértrique.
En déduire que toute matrice se décompose de façon unique en la somme d’une matrice symétrique et d’une matrice antisymétrique.
On tape :
A:=[[a00,a01,a02],[a10,a11,a12],[a20,a21,a22]]
B:=1/2*(A+tran(A));C:=1/2*(A-tran(A))
normal(B-tran(B)),normal(C+tran(C))
On obtient :
[[0,0,0],[0,0,0],[0,0,0]],[[0,0,0],[0,0,0],[0,0,0]]
Si A=M+N avec tran(M)=M et tran(N)=−N alors tran(A)=M−N donc
M=1/2*(A+tran(A))=B et N=1/2*(A−tran(A))=C d’où l’unicité.

### 5.2.2 Les matrices magiques d’odre 3

Une matrice A=(aj,k) d’ordre 3 est une matrice magique de somme s lorsque les 8 sommes :
∑j=02aj,k=s pour k=0,1,2 (somme de chaque colonne)
∑k=02aj,k=s pour j=0,1,2 (somme de chaque ligne)
∑j=02aj,j=a1,3+a2,2+a3,1=s (somme de chaque diagonale).
Déterminer les matrices magiques d’ordre 3 qui sont antisymétriques.
Déterminer les matrices magiques d’ordre 3 qui sont symétriques de somme s=0.
Déterminer une matrice magique d’ordre 3, symétrique, de somme s et la plus simple possible.
Montrer que la différence de 2 matrices symétriques magiques de somme s est une matrices symétriques magiques de somme s=0.
En déduire toutes les matrices magiques d’ordre 3, symétriques de somme s.
Trouver toutes les matrices magiques d’ordre 3 de somme s=3.
Trouver toutes les matrices magiques d’ordre 3 de somme s=9.
Les matrices magiques d’ordre 3 qui sont antisymétriques sont de somme s=0 car la diagonale principale ne contient que des 0.
Soit A une matrice antisymétrique d’ordre 3 et magique de somme s=0.
On tape :
A:=[[0,a,b],[-a,0,c],[-b,-c,0]]
linsolve([a+b=0,-a+c=0,b+c=0],[a,b,c])
On obtient :
[c,-c,c]
Donc les matrices magiques A d’ordre 3 qui sont antisymétriques sont :
A=(

0 | c | −c
−c | 0 | c
c | −c | 0

)=c(

0 | 1 | −1
−1 | 0 | 1
1 | −1 | 0

)
On tape :
A:=c*[[0,1,-1],[-1,0,1],[1,-1,0]]
Soit S une matrice symétrique d’ordre 3 et magique de somme s=0.
On tape :
S:=[[a,b,c],[b,d,e],[c,e,f]]
linsolve([a+b+c,a+d+f,b+d+e,c+e+f,2c+d],[a,b,c,d,e,f])
On obtient :
[-f,f,0,0,-f,f]
Donc les matrices magiques S d’ordre 3 qui sont symétriques de somme s=0 sont :
S=(

−f | f | 0
f | 0 | −f
0 | −f | f

)=f(

−1 | 1 | 0
1 | 0 | −1
0 | −1 | 1

)
Soit S0 une matrice symétrique d’ordre 3 et magique de somme s la plus simple possible.
On tape :
S0:=s/3*[[1,1,1],[1,1,1],[1,1,1]]
Donc les matrices magiques S d’ordre 3 qui sont symétriques de somme s sont B:=S+S0:
On tape :
B:=f*[[-1,1,0],[1,0,-1],[0,-1,1]]+
s/3*[[1,1,1],[1,1,1],[1,1,1]]
Donc les matrices magiques M d’ordre 3 qui sont de somme s=3 (resp s=12) sont M:=A+S+S0 et elles dépendent de 2 paramètres c et f.
On tape :
M:=c*[[0,1,-1],[-1,0,1],[1,-1,0]]+
f*[[-1,1,0],[1,0,-1],[0,-1,1]]+[[1,1,1],[1,1,1],[1,1,1]]
On obtient :
[[-f+1,c+f+1,-c+1],[-c+f+1,1,c-f+1],[c+1,-c-f+1,f+1]] Par exemple f=1,c=0, on obtient [[0,2,1],[2,1,0],[1,0,2]].
On tape :
M:=c*[[0,1,-1],[-1,0,1],[1,-1,0]]+
f*[[-1,1,0],[1,0,-1],[0,-1,1]]+4*[[1,1,1],[1,1,1],[1,1,1]]
On obtient :
[[-f+4,c+f+4,-c+4],[-c+f+4,4,c-f+4],[c+4,-c-f+4,f+4]]
Par exemple f=1,c=3, on obtient [[3,8,1],[2,4,6],[7,0,5]]

Retour à la page personnelle de Bernard Parisse.