# Maintainer: Marvin Zhang <marvin.beeblebrox@gmail.com>
# Contributor: Caleb Maclennan <caleb@alerque.com>

_realname=markdown-oxide
pkgbase=mingw-w64-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=0.25.10
pkgrel=1
pkgdesc='PKM oriented Markdown Language Server with Obsidian syntax support (mingw-w64)'
arch=('any')
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
url="https://github.com/Feel-ix-343/${_realname}"
msys2_repository_url="https://github.com/Feel-ix-343/${_realname}"
msys2_references=(
  'archlinux: markdown-oxide'
  'purl: pkg:github/Feel-ix-343/markdown-oxide'
)
license=('spdx:Apache-2.0')
depends=("${MINGW_PACKAGE_PREFIX}-cc-libs")
makedepends=("${MINGW_PACKAGE_PREFIX}-rust" "${MINGW_PACKAGE_PREFIX}-git")
options=('!strip')
_archive="${_realname}-${pkgver}"
source=("${url}/archive/v${pkgver}/${_archive}.tar.gz")
sha256sums=('67217dc2f460a21bf64493d2ebe860cb93563a62aa5eecc28c24cf38ee7100ed')
noextract=("${_archive}.tar.gz")

prepare() {
  mkdir -p "${_archive}"
  tar -xzf "${_archive}.tar.gz" --exclude="${_archive}/README.md" --strip-components=1 -C "${_archive}"
  
  cd "${_archive}"
  cp "docs/Markdown Oxide Docs/README.md" "README.md"
  
  cargo fetch --locked --target "${RUST_CHOST}" --config 'net.git-fetch-with-cli=true'
}

build() {
  cd "${_archive}"
  export RUSTFLAGS="${RUSTFLAGS/+crt-static/-crt-static}"
  cargo build --release --frozen --config 'net.git-fetch-with-cli=true'
}

package() {
  cd "${_archive}"
  install -Dm0755 -t "${pkgdir}${MINGW_PREFIX}/bin" "target/release/${_realname}"
  install -Dm0644 LICENSE -t "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/"
}
