# Maintainer: Maksim Bondarenkov <maksapple2306@gmail.com>

_realname=wasm-pkg-tools
pkgbase=mingw-w64-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=0.15.0
pkgrel=1
pkgdesc="Tools to package up Wasm Components (mingw-w64)"
url="https://github.com/bytecodealliance/wasm-pkg-tools"
msys2_repository_url="https://github.com/bytecodealliance/wasm-pkg-tools"
arch=('any')
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
license=('spdx:Apache-2.0')
depends=("${MINGW_PACKAGE_PREFIX}-rust")
makedepends=('git')
source=("git+https://github.com/bytecodealliance/wasm-pkg-tools.git#tag=v${pkgver}")
sha256sums=('f088deb1ed835f3deee36ae7bd67e6d92edf5afcef27d19468278e318505b496')

prepare() {
  cd ${_realname}
  cargo fetch --locked --target "${RUST_CHOST}"
}

build() {
  cd ${_realname}
  cargo build --release --frozen
}

package() {
  cd ${_realname}
  install -Dm755 target/release/wkg -t "${pkgdir}${MINGW_PREFIX}"/bin
  install -Dm644 LICENSE -t "${pkgdir}${MINGW_PREFIX}"/share/licenses/${_realname}
}
