# Contributor: Dirk Stolle

_realname=babel
pkgname=python-babel
pkgver=2.17.0
pkgrel=1
pkgdesc='Internationalization utilities'
arch=('any')
url='https://babel.pocoo.org/'
msys2_repository_url="https://github.com/python-babel/babel"
msys2_changelog_url='https://fishshell.com/docs/current/relnotes.html'
msys2_references=(
  'cygwin: python-babel'
  'cpe: cpe:/a:pocoo:babel'
  'purl: pkg:pypi/babel'
)
license=('spdx:BSD-3-Clause')
depends=('python')
makedepends=(
  'python-build'
  'python-installer'
  'python-setuptools'
)
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
sha256sums=('0c54cffb19f690cdcc52a3b50bcbf71e07a808d1c80d549f2459b9d2cf0afb9d')

build() {
  cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "python-build-${MSYSTEM}"

  python -m installer --prefix=${MSYSTEM_PREFIX} --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSE "${pkgdir}${MSYSTEM_PREFIX}/share/licenses/python-${_realname}/LICENSE"
}
